#!/usr/bin/perl -wl
use strict;
use Getopt::Long;
use File::Temp qw{tempfile tempdir};

my ($FALSE, $TRUE) = (0,1);

(my $myname = $0) =~ s#\A.*/##;

sub fatal($) {
    my ($msg) = @_;

    print(STDERR "$msg\n");
    exit(1);
}

my ($Twid, $Thgt, $tmpdir, $norepeat, $verbose);

# set defaults
$Twid = 600;
$Thgt = 8;
$tmpdir = $ENV{"TMPDIR"} || "/tmp";
$norepeat = $FALSE;
$verbose = $FALSE;

GetOptions("width=i"   => \$Twid,
           "height=i"  => \$Thgt,
           "tmpdir=s"  => \$tmpdir,
           "norepeat!" => \$norepeat,
           "verbose!"  => \$verbose);

if ($Twid < 1 || $Thgt < 1) {
    fatal("invalid width and/or height");
}
my $verboseCommand = $verbose ? "set -x;" : "";

if (@ARGV < 1) {
    fatal("You must specify at least one color as an argument");
} elsif (@ARGV < 2 && $norepeat) {
    fatal("With the -norepeat option, you must specify at least two colors " .
          "as arguments.");
}

my @colorlist;

@colorlist = @ARGV;
if (!$norepeat) {
    push @colorlist, $ARGV[0];
}

my $ourtmp = tempdir("ppmrainbow.XXXX", DIR => $tmpdir, CLEANUP => 1);
my $widthRemaining;
my @outlist;

$widthRemaining = $Twid;
@outlist = ();

while (@colorlist >= 2) {
    (my $tmpfh, my $outfile) = tempfile("file.XXXXXXXX", DIR => "$ourtmp", SUFFIX => '.ppm');
    push(@outlist, $outfile);

    my $w = int(($widthRemaining-1)/(@colorlist-1))+1;
    my $content = qx{$verboseCommand pgmramp -lr $w $Thgt | 
                     pgmtoppm "$colorlist[0]-$colorlist[1]"};
    if (! "$content") {
        fatal("pgmramp|pgmtoppm failed.");
    }
    print $tmpfh $content;
    $widthRemaining -= $w;
    shift @colorlist;
}

0 == system qq{$verboseCommand pnmcat -lr @outlist}
    or exit 1;

exit 0;

END {
    if (@outlist) {
        unlink(@outlist);
    }
    if (defined($ourtmp)) {
        rmdir($ourtmp);
    }
}
